Database Connectie (.mdb) : getrows
klant_id klantnaam plaats
1 Maertens Brugge
2 Deblaere Gent
3 Vanzever Brugge
4 Vermander Brugge
5 Willems Gent
6 Peeters Brugge
7 Peeters Oostende
8 Holvoet Oostende
9 Braet Brugge
10 Arnolds Blankenberge 
Code :


<%@enablesessionstate=false%>
	<!-- Geen gebruik van sesseivariabelen op deze pagina -->
<%response.buffer=true%>
<html>
<head>
	<TITLE>Database : getrows</TITLE>
	<link href="../stijl.css" rel="stylesheet">
</head>
<body bgcolor="#FFFFFF">
<% 
DB = "biblio_2000.mdb"
Path = Server.MapPath(DB)
set DataConn = server.Createobject("ADODB.Connection")
DataConn.Open "Data Source=" & Path & ";Provider=Microsoft.Jet.OLEDB.4.0;"
Set rs = Server.CreateObject("ADODB.Recordset")


rs.Open "SELECT * FROM klant", DataConn

If  rs.eof then
   response.write "Geen records<br>"
   Call Sluit
   response.end
end if

response.write "<table border='1'><tr>" & vbcrlf
'Hoofdingen
for each veld in rs.fields
   response.write "<td><b>" & veld.name & "</B></TD>" & vbcrlf
next
response.write "</tr>" & vbcrlf

' alle records
alldata=rs.getrows
Call Sluit

numcols=ubound(alldata,1)
numrows=ubound(alldata,2)
FOR rij= 0 TO numrows
   response.write "<tr>" & vbcrlf
   FOR kol=0 to numcols
      veldwaarde=alldata(kol,rij)
      if isnull(veldwaarde) then
         veldwaarde="-null-"
      end if
      if trim(veldwaarde)="" then
         veldwaarde=" "
      end if
      response.write "<td>" &veldwaarde &"</td>" & vbcrlf
   NEXT
   response.write "</tr>" & vbcrlf
NEXT
response.write "</table>" 
%>

</body></html>
<%
SUB Sluit
   rs.close
   set rs=nothing
   dataconn.close
   set dataconn=nothing
END SUB
%>


Uitleg :


De methode getrows van een recordset-object zorgt ervoor dat de recordset wordt geplaatst in een tweedimensionale Array.

Deze Array bevat als eerste dimensie het aantal kolommen en als tweede dimensie het aantal rijen van de recordset.

Dit specifieke voorbeeld geeft je een algemene manier om de inhoud van een recordset op het scherm te brengen.