Cursus ASP : Werken met Cookies
Een test met een cookie
Pietje

ASP.NET_SessionId = 1ssmcz452hld3x55sw0es1jn
Testcookie = Een test met een cookie
Gebruiker(Voornaam) = Pietje
Gebruiker(Naam) = Pek

Code :


<%
Response.cookies("Testcookie").expires = "1/30/2004"
Response.cookies("Testcookie")="Een test met een cookie"

Response.cookies("Gebruiker").expires = "1/30/2004"
Response.cookies("Gebruiker")("Naam") = "Pek"
Response.cookies("Gebruiker")("Voornaam") = "Pietje"

response.write request.cookies("Testcookie") &"<BR>"
response.write request.cookies("Gebruiker")("Voornaam") &"<P>"

for each cnaam in request.cookies
	if request.cookies(cnaam).haskeys then
		for each knaam in request.cookies(cnaam)
			response.write cnaam &"(" &knaam &") = " _
			&request.cookies(cnaam)(knaam) &"<BR>"
		next
	else
		response.write cnaam &" = " &request.cookies(cnaam) &"<BR>"
	end if
next
%>


Uitleg :


Cookies zijn tekstbestandjes die op de harde schijf van de gebruiker worden weggeschreven
in die bestandjes kan je vanop een website informatie wegschrijven en uitlezen.

Cookies kunnen op twee manieren weggeschreven worden :

- met response.cookies(naam van de cookie) voor een cookie bestaand uit 1 waarde
- met response.cookies(naam van de cookie)(naam van de sleutel) voor een cookie bestaand uit
  meerdere waarden
  
Je kan een cookie een vervaldatum meegeven met :
  response.cookie(naam van de cookie).expires = "datum"
Na die datum wordt de cookie verwijderd
  
Cookies worden uitgelezen met request.cookie(naam van de cookie) 
en optioneel (naam van de sleutel)

In dit voorbeeld wordt ook een for...each lus gebruikt om doorheen de cookies te lussen
en de waarde ervan op het scherm te brengen.
Er wordt hierbij een onderscheid gemaakt tussen cookies met en zonder sleutelwaarden.