Code :
<%@ LANGUAGE="VBSCRIPT" %>
<%
DB = "biblio_2000.mdb"
Path = Server.MapPath(DB)
set DataConn = server.Createobject("ADODB.Connection")
DataConn.Open "Data Source=" & Path & ";Provider=Microsoft.Jet.OLEDB.4.0;"
Set rs = Server.CreateObject("ADODB.Recordset")
rs.Open "SELECT * FROM klant", DataConn
strRS = rs.Getstring(,,"</td><td>","</td></tr>" &vbcrlf &"<tr><td>"," ") %>
<HTML>
<HEAD>
<TITLE>Databases : getstring</TITLE>
</HEAD>
<BODY>
<%
response.write "<table border='1'><tr>" & vbcrlf
'Hoofdingen
for each veld in rs.fields
response.write "<td><b>" & veld.name & "</B></TD>" & vbcrlf
next
RS.close
set RS= nothing
DataConn.close
set DataConn = nothing
response.write "</tr>" & vbcrlf
%>
<TR><TD>
<% Response.Write(strRS) %>
</TD></TR>
</TABLE>
</BODY>
</HTML>
Uitleg :
Met getstring methode kan je een recordset in een stringvariabele 'dumpen'.
Hierbij geld de volgende syntax :
recordset.GetString(StringFormat, NumRows, ColumnDelimiter, RowDelimiter, NullExpr)
Het eerste argument Stringformat is eigenlik overbodig daar er slechts één formaat is, welke standaard aangewend wordt.
Met Numrows geef je eventueel aan hoeveel rijen je wenst uit te lezen,
indien niet opgegeven wordt de volledige recordset in de string gestopt.
Columndelimeter en Rowdelimeter zijn respectievelijk de in te voegen tekens na een kolom en na een rij van de recordset.
Zo kan je er voor zorgen dat met een goede keuze van de delimeters de recordset rijen en datacellen van een HTML-tabel vormen.
Je kan met deze methode onmiddellijk na de getstring de recordset en dataconnectie sluiten.
De ganse recordset zit nu in een stringvariabele die je nu verder kan gebruiken.
In dit voorbeeld wordt echter eerst met een for..each lus aangetoond
hoe je de veldnamen van een recordset op het scherm kan krijgen.